GUFFA | FOTO | PROGRAMMERING | GÄSTBOK

ASP : Kalender

Den här koden visar en tabell med dagarna i en månad.

Tabellen är sju kolumner bred och visar måndag till söndag, raderna i kolumnen är veckor. Den första och sista raden fylls ut med tomma celler för de dagar i veckorna som tillhör föregående och nästa månad.

<%
Dim lngYear, lngMonth, lngDay, lngWeekday, lngLastDay, datMonth

' välj år och månad

lngYear = Year(Date())
lngMonth = Month(Date())

' första dagen i månaden

datMonth = DateSerial(lngYear, lngMonth, 1)

' datum för första rutan i tabellen

lngDay = 2 - Weekday(datMonth, vbMonday)
' antal dagar i månaden

lngLastDay = DateDiff("d", datMonth, DateAdd("m", 1, datMonth))

%><table border="1"><%
' loopa igenom alla veckor

Do
   %><tr><%
   ' loopa igenom en vecka
   For lngWeekday=1 to 7
      ' kolla om cellen är med i månaden
      If lngDay>=1 and lngDay<=lngLastDay Then
         ' visa datum
         %><td><%=lngDay%></td><%
      Else
         ' visa en tom cell
         %><td>&nbsp;</td><%
      End If
      lngDay=lngDay+1
   Next
   %></tr><%
Loop until lngDay>lngLastDay
%>
</table>